Potenziale insespresso

[xo66]

Ciao ragazzi,
è da settimane che provo a dare soluzione a formula.
Nel file che vi allego ho le vendite su due anni e su due misure (YTD Year To Date e MAT Moving Annual Total) diviso per classificazione di prodotti (Categoria e Sottocategoria) e per clienti. Per ognuno di questi ho le vendite complessive del mercato e di un particolare fornitore (UNI_FS).
Ho messo nella colonna AA il risultato che vorrei ricevere: ovvero, conoscendo la quota del mercato Italia MS% di ogni classificazione di prodotto (categoria e sottocategoria) e conoscendo la quota di mercato di ogni punto vendita, vorrei sapere il potenziale inespresso che ogni punto vendita potrebbe raggiungere nel caso in cui la loro quota di mercato fosse più bassa della media nazionale. Ma fin qui è facile.... vorrei fare in modo che il totale di ogni classificazione si basasse sulla somma di ogni precedente di classificazione prodotto (categoria e sottocategoria).

Grazie in anticipo per l'aiuto.

[Andrea90]

Ciao xo66,

Non sono sicuro di aver compreso bene la logica di calcolo.

Ti faccio un esempio, nel tuo file, alla riga 18 del campo target desiderato, mi sarei aspettato 20.485 e non 34.756, perchè hai aggiunto anche il subtotale del campo mercato "Verdura" ?

A presto,

Andrea

[xo66]

Si scusa... hai ragione.... 20.485... è che ho dovuto modificare cancellare records dal file per caricarlo dato che superava 1Mb e non ho modificato le formule....

[Andrea90]

Allora proverei queste due misure:

[Misura1]

Codice: Seleziona tutto

=
MAX (
    0;
     (
        CALCULATE ( [ITA_€_ms%_ACT]; 'dataset'[Azienda] = "UNI_FS" )
            * CALCULATE ( [f_€_ACT]; 'dataset'[Azienda] = "mercato" )
    )
        - CALCULATE ( [f_€_ACT]; 'dataset'[Azienda] = "UNI_FS" )
)

[Misura2]

Codice: Seleziona tutto

=
VAR Tabella =
    SUMMARIZE (
        'dataset';
        [Ragione Sociale];
        'dataset'[Codice Interno];
        'dataset'[Località];
        'dataset'[Prov];
        'dataset'[Mercato];
        'dataset'[Categoria];
        'dataset'[Sottocategoria]
    )
VAR TabellaAdd =
    ADDCOLUMNS ( Tabella; "#Measure"; [Misura1] )
RETURN
    SUMX ( TabellaAdd; [#Measure] )

Nella seconda misura c'è il riferimento alla prima, quindi presta attenzione a richiamarla con il nome che poi sceglierai.

A presto,
Andrea

[xo66]

Grazie mille Andrea! Sei stato velocissimo... ci provo domani e ti faccio sapere.

[xo66]

SUPER! Funziona!!!! Grazie mille